home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / window.el.z / window.el
Encoding:
Text File  |  1998-10-28  |  10.9 KB  |  289 lines
  1. ;;; window.el --- GNU Emacs window commands aside from those written in C.
  2.  
  3. ;; Copyright (C) 1985, 1989, 1992, 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6.  
  7. ;; This file is part of GNU Emacs.
  8.  
  9. ;; GNU Emacs is free software; you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation; either version 2, or (at your option)
  12. ;; any later version.
  13.  
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;; GNU General Public License for more details.
  18.  
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22. ;; Boston, MA 02111-1307, USA.
  23.  
  24. ;;; Code:
  25.  
  26. ;;;; Window tree functions.
  27.  
  28. (defun one-window-p (&optional nomini all-frames)
  29.   "Returns non-nil if the selected window is the only window (in its frame).
  30. Optional arg NOMINI non-nil means don't count the minibuffer
  31. even if it is active.
  32.  
  33. The optional arg ALL-FRAMES t means count windows on all frames.
  34. If it is `visible', count windows on all visible frames.
  35. ALL-FRAMES nil or omitted means count only the selected frame, 
  36. plus the minibuffer it uses (which may be on another frame).
  37. If ALL-FRAMES is neither nil nor t, count only the selected frame."
  38.   (let ((base-window (selected-window)))
  39.     (if (and nomini (eq base-window (minibuffer-window)))
  40.     (setq base-window (next-window base-window)))
  41.     (eq base-window
  42.     (next-window base-window (if nomini 'arg) all-frames))))
  43.  
  44. (defun walk-windows (proc &optional minibuf all-frames)
  45.   "Cycle through all visible windows, calling PROC for each one.
  46. PROC is called with a window as argument.
  47.  
  48. Optional second arg MINIBUF t means count the minibuffer window even
  49. if not active.  MINIBUF nil or omitted means count the minibuffer iff
  50. it is active.  MINIBUF neither t nor nil means not to count the
  51. minibuffer even if it is active.
  52.  
  53. Several frames may share a single minibuffer; if the minibuffer
  54. counts, all windows on all frames that share that minibuffer count
  55. too.  Therefore, if you are using a separate minibuffer frame
  56. and the minibuffer is active and MINIBUF says it counts,
  57. `walk-windows' includes the windows in the frame from which you
  58. entered the minibuffer, as well as the minibuffer window.
  59.  
  60. ALL-FRAMES is the optional third argument.
  61. ALL-FRAMES nil or omitted means cycle within the frames as specified above.
  62. ALL-FRAMES = `visible' means include windows on all visible frames.
  63. ALL-FRAMES = 0 means include windows on all visible and iconified frames.
  64. ALL-FRAMES = t means include windows on all frames including invisible frames.
  65. Anything else means restrict to the selected frame."
  66.   ;; If we start from the minibuffer window, don't fail to come back to it.
  67.   (if (window-minibuffer-p (selected-window))
  68.       (setq minibuf t))
  69.   (let* ((walk-windows-start (selected-window))
  70.      (walk-windows-current walk-windows-start))
  71.     (while (progn
  72.          (setq walk-windows-current
  73.            (next-window walk-windows-current minibuf all-frames))
  74.          (funcall proc walk-windows-current)
  75.          (not (eq walk-windows-current walk-windows-start))))))
  76.  
  77. (defun minibuffer-window-active-p (window)
  78.   "Return t if WINDOW (a minibuffer window) is now active."
  79.   (eq window (active-minibuffer-window)))
  80.  
  81. (defmacro save-selected-window (&rest body)
  82.   "Execute BODY, then select the window that was selected before BODY."
  83.   (list 'let
  84.     '((save-selected-window-window (selected-window)))
  85.     (list 'unwind-protect
  86.           (cons 'progn body)
  87.           (list 'select-window 'save-selected-window-window)))) 
  88.  
  89. (defun count-windows (&optional minibuf)
  90.    "Returns the number of visible windows.
  91. Optional arg MINIBUF non-nil means count the minibuffer
  92. even if it is inactive."
  93.    (let ((count 0))
  94.      (walk-windows (function (lambda (w)
  95.                    (setq count (+ count 1))))
  96.            minibuf)
  97.      count))
  98.  
  99. (defun balance-windows ()
  100.   "Makes all visible windows the same height (approximately)."
  101.   (interactive)
  102.   (let ((count -1) levels newsizes size
  103.     ;; Don't count the lines that are above the uppermost windows.
  104.     ;; (These are the menu bar lines, if any.)
  105.     (mbl (nth 1 (window-edges (frame-first-window (selected-frame))))))
  106.     ;; Find all the different vpos's at which windows start,
  107.     ;; then count them.  But ignore levels that differ by only 1.
  108.     (save-window-excursion
  109.       (let (tops (prev-top -2))
  110.     (walk-windows (function (lambda (w)
  111.                   (setq tops (cons (nth 1 (window-edges w))
  112.                            tops))))
  113.               'nomini)
  114.     (setq tops (sort tops '<))
  115.     (while tops
  116.       (if (> (car tops) (1+ prev-top))
  117.           (setq prev-top (car tops)
  118.             count (1+ count)))
  119.       (setq levels (cons (cons (car tops) count) levels))
  120.       (setq tops (cdr tops)))
  121.     (setq count (1+ count))))
  122.     ;; Subdivide the frame into that many vertical levels.
  123.     (setq size (/ (- (frame-height) mbl) count))
  124.     (walk-windows (function
  125.            (lambda (w)
  126.              (select-window w)
  127.              (let ((newtop (cdr (assq (nth 1 (window-edges))
  128.                           levels)))
  129.                (newbot (or (cdr (assq (+ (window-height)
  130.                              (nth 1 (window-edges)))
  131.                           levels))
  132.                        count)))
  133.                (setq newsizes
  134.                  (cons (cons w (* size (- newbot newtop)))
  135.                    newsizes)))))
  136.           'nomini)
  137.     (walk-windows (function (lambda (w)
  138.                   (select-window w)
  139.                   (let ((newsize (cdr (assq w newsizes))))
  140.                 (enlarge-window (- newsize
  141.                            (window-height))))))
  142.           'nomini)))
  143.  
  144. ;;; I think this should be the default; I think people will prefer it--rms.
  145. (defvar split-window-keep-point t
  146.   "*If non-nil, split windows keeps the original point in both children.
  147. This is often more convenient for editing.
  148. If nil, adjust point in each of the two windows to minimize redisplay.
  149. This is convenient on slow terminals, but point can move strangely.")
  150.  
  151. (defun split-window-vertically (&optional arg)
  152.   "Split current window into two windows, one above the other.
  153. The uppermost window gets ARG lines and the other gets the rest.
  154. Negative arg means select the size of the lowermost window instead.
  155. With no argument, split equally or close to it.
  156. Both windows display the same buffer now current.
  157.  
  158. If the variable split-window-keep-point is non-nil, both new windows
  159. will get the same value of point as the current window.  This is often
  160. more convenient for editing.
  161.  
  162. Otherwise, we chose window starts so as to minimize the amount of
  163. redisplay; this is convenient on slow terminals.  The new selected
  164. window is the one that the current value of point appears in.  The
  165. value of point can change if the text around point is hidden by the
  166. new mode line."
  167.   (interactive "P")
  168.   (let ((old-w (selected-window))
  169.     (old-point (point))
  170.     (size (and arg (prefix-numeric-value arg)))
  171.         (window-full-p nil)
  172.     new-w bottom switch moved)
  173.     (and size (< size 0) (setq size (+ (window-height) size)))
  174.     (setq new-w (split-window nil size))
  175.     (or split-window-keep-point
  176.     (progn
  177.       (save-excursion
  178.         (set-buffer (window-buffer))
  179.         (goto-char (window-start))
  180.             (setq moved (vertical-motion (window-height)))
  181.         (set-window-start new-w (point))
  182.         (if (> (point) (window-point new-w))
  183.         (set-window-point new-w (point)))
  184.             (and (= moved (window-height))
  185.                  (progn
  186.                    (setq window-full-p t)
  187.                    (vertical-motion -1)))
  188.             (setq bottom (point)))
  189.           (and window-full-p
  190.                (<= bottom (point))
  191.                (set-window-point old-w (1- bottom)))
  192.       (and window-full-p
  193.                (<= (window-start new-w) old-point)
  194.                (progn
  195.                  (set-window-point new-w old-point)
  196.                  (select-window new-w)))))
  197.     new-w))
  198.  
  199. (defun split-window-horizontally (&optional arg)
  200.   "Split current window into two windows side by side.
  201. This window becomes the leftmost of the two, and gets ARG columns.
  202. Negative arg means select the size of the rightmost window instead.
  203. No arg means split equally."
  204.   (interactive "P")
  205.   (let ((size (and arg (prefix-numeric-value arg))))
  206.     (and size (< size 0)
  207.      (setq size (+ (window-width) size)))
  208.     (split-window nil size t)))
  209.  
  210. (defun enlarge-window-horizontally (arg)
  211.   "Make current window ARG columns wider."
  212.   (interactive "p")
  213.   (enlarge-window arg t))
  214.  
  215. (defun shrink-window-horizontally (arg)
  216.   "Make current window ARG columns narrower."
  217.   (interactive "p")
  218.   (shrink-window arg t))
  219.  
  220. (defun shrink-window-if-larger-than-buffer (&optional window)
  221.   "Shrink the WINDOW to be as small as possible to display its contents.
  222. Do not shrink to less than `window-min-height' lines.
  223. Do nothing if the buffer contains more lines than the present window height,
  224. or if some of the window's contents are scrolled out of view,
  225. or if the window is not the full width of the frame,
  226. or if the window is the only window of its frame."
  227.   (interactive)
  228.   (or window (setq window (selected-window)))
  229.   (save-excursion
  230.     (set-buffer (window-buffer window))
  231.     (let* ((w (selected-window))    ;save-window-excursion can't win
  232.        (buffer-file-name buffer-file-name)
  233.        (p (point))
  234.        (n 0)
  235.        (ignore-final-newline
  236.         ;; If buffer ends with a newline, ignore it when counting height
  237.         ;; unless point is after it.
  238.         (and (not (eobp))
  239.          (eq ?\n (char-after (1- (point-max))))))
  240.        (buffer-read-only nil)
  241.        (modified (buffer-modified-p))
  242.        (buffer (current-buffer))
  243.        (params (frame-parameters (window-frame window)))
  244.        (mini (cdr (assq 'minibuffer params)))
  245.        (edges (window-edges (selected-window))))
  246.       (if (and (< 1 (let ((frame (selected-frame)))
  247.               (select-frame (window-frame window))
  248.               (unwind-protect
  249.               (count-windows)
  250.             (select-frame frame))))
  251.            (= (window-width window) (frame-width (window-frame window)))
  252.            (pos-visible-in-window-p (point-min) window)
  253.            (not (eq mini 'only))
  254.            (or (not mini)
  255.            (< (nth 3 edges)
  256.               (nth 1 (window-edges mini)))
  257.            (> (nth 1 edges)
  258.               (cdr (assq 'menu-bar-lines params)))))
  259.       (unwind-protect
  260.           (progn
  261.         (select-window (or window w))
  262.         (goto-char (point-min))
  263.         (while (pos-visible-in-window-p
  264.             (- (point-max)
  265.                (if ignore-final-newline 1 0)))
  266.           ;; defeat file locking... don't try this at home, kids!
  267.           (setq buffer-file-name nil)
  268.           (insert ?\n) (setq n (1+ n)))
  269.         (if (> n 0)
  270.             (shrink-window (min (1- n)
  271.                     (- (window-height)
  272.                        window-min-height)))))
  273.         (delete-region (point-min) (point))
  274.         (set-buffer-modified-p modified)
  275.         (goto-char p)
  276.         (select-window w)
  277.         ;; Make sure we unbind buffer-read-only
  278.         ;; with the proper current buffer.
  279.         (set-buffer buffer))))))
  280.       
  281. (define-key ctl-x-map "2" 'split-window-vertically)
  282. (define-key ctl-x-map "3" 'split-window-horizontally)
  283. (define-key ctl-x-map "}" 'enlarge-window-horizontally)
  284. (define-key ctl-x-map "{" 'shrink-window-horizontally)
  285. (define-key ctl-x-map "-" 'shrink-window-if-larger-than-buffer)
  286. (define-key ctl-x-map "+" 'balance-windows)
  287.  
  288. ;;; windows.el ends here
  289.